Added Cyg-Win

Agent-Windows/OGP64/usr/share/perl5/5.40/Digest/base.pm

@@ -0,0 +1,106 @@
+package Digest::base;
+
+use strict;
+use warnings;
+
+our $VERSION = "1.20";
+
+# subclass is supposed to implement at least these
+sub new;
+sub clone;
+sub add;
+sub digest;
+
+sub reset {
+    my $self = shift;
+    $self->new(@_);    # ugly
+}
+
+sub addfile {
+    my ( $self, $handle ) = @_;
+
+    my $n;
+    my $buf = "";
+
+    while ( ( $n = read( $handle, $buf, 4 * 1024 ) ) ) {
+        $self->add($buf);
+    }
+    unless ( defined $n ) {
+        require Carp;
+        Carp::croak("Read failed: $!");
+    }
+
+    $self;
+}
+
+sub add_bits {
+    my $self = shift;
+    my $bits;
+    my $nbits;
+    if ( @_ == 1 ) {
+        my $arg = shift;
+        $bits  = pack( "B*", $arg );
+        $nbits = length($arg);
+    }
+    else {
+        ( $bits, $nbits ) = @_;
+    }
+    if ( ( $nbits % 8 ) != 0 ) {
+        require Carp;
+        Carp::croak("Number of bits must be multiple of 8 for this algorithm");
+    }
+    return $self->add( substr( $bits, 0, $nbits / 8 ) );
+}
+
+sub hexdigest {
+    my $self = shift;
+    return unpack( "H*", $self->digest(@_) );
+}
+
+sub b64digest {
+    my $self = shift;
+    my $b64  = $self->base64_padded_digest;
+    $b64 =~ s/=+$//;
+    return $b64;
+}
+
+sub base64_padded_digest {
+    my $self = shift;
+    require MIME::Base64;
+    return MIME::Base64::encode( $self->digest(@_), "" );
+}
+
+1;
+
+__END__
+
+=head1 NAME
+
+Digest::base - Digest base class
+
+=head1 SYNOPSIS
+
+  package Digest::Foo;
+  use base 'Digest::base';
+
+=head1 DESCRIPTION
+
+The C<Digest::base> class provide implementations of the methods
+C<addfile> and C<add_bits> in terms of C<add>, and of the methods
+C<hexdigest> and C<b64digest> in terms of C<digest>.
+
+Digest implementations might want to inherit from this class to get
+this implementations of the alternative I<add> and I<digest> methods.
+A minimal subclass needs to implement the following methods by itself:
+
+    new
+    clone
+    add
+    digest
+
+The arguments and expected behaviour of these methods are described in
+L<Digest>.
+
+=head1 SEE ALSO
+
+L<Digest>

Agent-Windows/OGP64/usr/share/perl5/5.40/Digest/file.pm

@@ -0,0 +1,83 @@
+package Digest::file;
+
+use strict;
+use warnings;
+
+use Exporter ();
+use Carp qw(croak);
+use Digest ();
+
+our $VERSION   = "1.20";
+our @ISA       = qw(Exporter);
+our @EXPORT_OK = qw(digest_file_ctx digest_file digest_file_hex digest_file_base64);
+
+sub digest_file_ctx {
+    my $file = shift;
+    croak("No digest algorithm specified") unless @_;
+    open( my $fh, "<", $file ) || croak("Can't open '$file': $!");
+    binmode($fh);
+    my $ctx = Digest->new(@_);
+    $ctx->addfile($fh);
+    close($fh);
+    return $ctx;
+}
+
+sub digest_file {
+    digest_file_ctx(@_)->digest;
+}
+
+sub digest_file_hex {
+    digest_file_ctx(@_)->hexdigest;
+}
+
+sub digest_file_base64 {
+    digest_file_ctx(@_)->b64digest;
+}
+
+1;
+
+__END__
+
+=head1 NAME
+
+Digest::file - Calculate digests of files
+
+=head1 SYNOPSIS
+
+  # Poor mans "md5sum" command
+  use Digest::file qw(digest_file_hex);
+  for (@ARGV) {
+      print digest_file_hex($_, "MD5"), "  $_\n";
+  }
+
+=head1 DESCRIPTION
+
+This module provide 3 convenience functions to calculate the digest
+of files.  The following functions are provided:
+
+=over
+
+=item digest_file( $file, $algorithm, [$arg,...] )
+
+This function will calculate and return the binary digest of the bytes
+of the given file.  The function will croak if it fails to open or
+read the file.
+
+The $algorithm is a string like "MD2", "MD5", "SHA-1", "SHA-512".
+Additional arguments are passed to the constructor for the
+implementation of the given algorithm.
+
+=item digest_file_hex( $file, $algorithm, [$arg,...] )
+
+Same as digest_file(), but return the digest in hex form.
+
+=item digest_file_base64( $file, $algorithm, [$arg,...] )
+
+Same as digest_file(), but return the digest as a base64 encoded
+string.
+
+=back
+
+=head1 SEE ALSO
+
+L<Digest>